Làm cách nào để tắt Hyper-V trong dòng lệnh?

Trong một Lệnh nâng cao, hãy viết điều này:

Để vô hiệu hóa:

bcdedit /set hypervisorlaunchtype off

Để bật:

bcdedit /set hypervisorlaunchtype auto 

(Từ ý kiến ​​- khởi động lại để có hiệu lực)

Lệnh này hoạt động

Disable-WindowsOptionalFeature -Online -FeatureName Microsoft-Hyper-V-All

Chạy nó sau đó đồng ý khởi động lại máy tính khi được nhắc.

Tôi đã chạy nó trong các quyền nâng cao PowerShell trên Windows 10, nhưng nó cũng hoạt động trên Win 8 hoặc 7.

Bạn có thể có cấu hình Windows 10 có và không có Hyper-V như sau trong lời nhắc của Quản trị viên:

bcdedit /copy {current} /d "Windows 10 no Hyper-V"

tìm id mới của bootentry "Windows 10 no Hyper-V" vừa tạo, vd. {094a0b01-3350-11e7-99e1-bc5ec82bc470}

bcdedit /set {094a0b01-3350-11e7-99e1-bc5ec82bc470} hypervisorlaunchtype Off

Sau khi khởi động lại, bạn có thể chọn giữa Windows 10 có và không có Hyper-V khi khởi động

Dòng lệnh:

dism /online /disable-feature /featurename:microsoft-hyper-v-all

Nếu bất cứ ai đang nhận được:

Chúng tôi không thể hoàn thành các bản cập nhật, Hoàn tác các thay đổi

sau khi thử tắt Hyper-V, hãy thử gỡ cài đặt bộ điều hợp mạng ảo Hyper-V khỏi Trình quản lý thiết bị của bạn-> Bộ điều hợp mạng

Mở một dấu nhắc lệnh với tư cách quản trị viên và chạy lệnh này:

bcdedit /set {current} hypervisorlaunchtype off

Sau khi khởi động lại, Hyper-V vẫn được cài đặt nhưng Hypervisor không còn chạy. Bây giờ bạn có thể sử dụng VMware mà không có bất kỳ vấn đề.

Nếu bạn cần Hyper-V một lần nữa, hãy mở một dấu nhắc lệnh với tư cách quản trị viên và chạy lệnh này:

bcdedit /set {current} hypervisorlaunchtype auto

bạn có thể sử dụng kịch bản của tôi. dán các dòng mã vào notepad và lưu dưới dạng vbs (ví dụ: switch_hypervisor.vbs)

Option Explicit

Dim backupfile
Dim record
Dim myshell
Dim appmyshell
Dim myresult
Dim myline
Dim makeactive
Dim makepassive
Dim reboot
record=""
Set myshell = WScript.CreateObject("WScript.Shell")

If WScript.Arguments.Length = 0 Then
    Set appmyshell  = CreateObject("Shell.Application")
    appmyshell.ShellExecute "wscript.exe", """" & WScript.ScriptFullName & """ RunAsAdministrator", , "runas", 1
    WScript.Quit
End if




Set backupfile = CreateObject("Scripting.FileSystemObject")
If Not (backupfile.FileExists("C:\bcdedit.bak")) Then
    Set myresult = myshell.Exec("cmd /c bcdedit /export c:\bcdedit.bak")
End If

Set myresult = myshell.Exec("cmd /c bcdedit")
Do While Not myresult.StdOut.AtEndOfStream
    myline = myresult.StdOut.ReadLine()

    If myline="The boot configuration data store could not be opened." Then
        record=""
        exit do
    End If
    If Instr(myline, "identifier") > 0 Then
        record=""
        If Instr(myline, "{current}") > 0 Then
            record="current"
        End If
    End If
    If Instr(myline, "hypervisorlaunchtype") > 0 And record = "current" Then
        If Instr(myline, "Auto") > 0 Then
            record="1"
            Exit Do
        End If
        If Instr(myline, "On") > 0 Then
            record="1"
            Exit Do
        End If
        If Instr(myline, "Off") > 0 Then
            record="0"
            Exit Do
        End If
    End If
Loop

If record="1" Then
    makepassive = MsgBox ("Hypervisor status is active, do you want set to passive? ", vbYesNo, "Hypervisor")
    Select Case makepassive
    Case vbYes
        myshell.run "cmd.exe /C  bcdedit /set hypervisorlaunchtype off"
        reboot = MsgBox ("Hypervisor chenged to passive; Computer must reboot. Reboot now? ", vbYesNo, "Hypervisor")
        Select Case reboot
            Case vbYes
                myshell.run "cmd.exe /C  shutdown /r /t 0"
        End Select
    Case vbNo
        MsgBox("Not Changed")
    End Select
End If

If record="0" Then
    makeactive = MsgBox ("Hypervisor status is passive, do you want set active? ", vbYesNo, "Hypervisor")
    Select Case makeactive
    Case vbYes
        myshell.run "cmd.exe /C  bcdedit /set hypervisorlaunchtype auto"
        reboot = MsgBox ("Hypervisor changed to active;  Computer must reboot. Reboot now?", vbYesNo, "Hypervisor")
        Select Case reboot
            Case vbYes
                myshell.run "cmd.exe /C  shutdown /r /t 0"
        End Select
    Case vbNo
        MsgBox("Not Changed")
    End Select
End If

If record="" Then
        MsgBox("Error: record can't find")
End If